10 RANDOMIZE TIMER:ON ERROR GOTO 9999:SCREEN 1,0:COLOR 0:CLS:GOSUB 5400
20 FOR L=0 TO 3:READ NU$(L):NEXT
22 N0$=STRING$(2,219)+STRING$(6,32)+STRING$(2,219):N1$=STRING$(2,219):N3$=STRING$(10,219):N5$=STRING$(6,219)
30 FOR L=0 TO 6:X(L)=40*L+32:Y(L)=152-L*24:NEXT
40 FOR L=1 TO 8:READ P$(L):NEXT
50 GOSUB 3000
60 GOSUB 5023:LOCATE 23,2:PRINT "Would you like instructions? (Y or N)";
62 GOSUB 80:IF IN$<>"Y" AND IN$<>"N" AND IN$<>CHR$(27) THEN 62
64 IF IN$=CHR$(27) THEN GOSUB 210:GOSUB 5025:GOTO 60
66 IF IN$="Y" THEN GOSUB 2000:SCREEN 1,0:COLOR 0
70 GOTO 1000
80 GOSUB 5110
82 GOSUB 5100:IN$=INKEY$:IF IN$="" THEN 82 ELSE IF LEN(IN$) <> 1 THEN GOSUB 5102:GOTO 82 ELSE GOSUB 5102:RETURN
100 CLS:LINE(20,64)-(295,71),3,BF:FOR L=36 TO 276 STEP 40:LINE(L,64)-(L+3,71),0,BF:NEXT
101 FOR L=-3 TO 3:AB=ABS(L):DRAW"C2BM"+STR$(X(L+3))+",84"+NU$(AB):PAINT(X(L+3)+6,85),2,2:GOSUB 330:IF L<0 THEN LINE(X(L+3)-12,92)-(X(L+3)-5,95),2,BF
102 NEXT:RETURN
110 CLS:LINE(156,4)-(163,167),3,BF:FOR L=12 TO 156 STEP 24:LINE(156,L)-(163,L+3),0,BF:NEXT
111 FOR L=-3 TO 3:AB=ABS(L):DRAW"C2BM134,"+STR$(Y(L+3)-4)+NU$(AB):PAINT(140,Y(L+3)-3),2,2:GOSUB 330:IF L<0 THEN LINE(122,Y(L+3)+8)-(129,Y(L+3)+11),2,BF
112 NEXT:RETURN
120 IF A1=1 THEN 124
122 COL=2:GOSUB 126:RETURN
124 COL=1:GOSUB 126:RETURN
126 LINE(X(X1+3)-2,58)-(X(X1+3)+3,77),COL,BF:LINE(X(Y1+3)+8,58)-(X(Y1+3)+13,77),COL,BF:LINE(X(X1+3)-2,58)-(X(Y1+3)+13,63),COL,BF:LINE(X(X1+3)-2,72)-(X(Y1+3)+13,77),COL,BF:RETURN
130 IF A2=1 THEN 134
132 COL=2:GOSUB 136:RETURN
134 COL=1:GOSUB 136:RETURN
136 LINE(150,Y(X2+3)+8)-(169,Y(X2+3)+13),COL,BF:LINE(150,Y(Y2+3)-2)-(169,Y(Y2+3)+3),COL,BF:LINE(150,Y(Y2+3)-2)-(155,Y(X2+3)+13),COL,BF:LINE(164,Y(Y2+3)-2)-(169,Y(X2+3)+13),COL,BF:RETURN
140 LINE(30,58)-(285,63),0,BF:LINE(30,72)-(285,77),0,BF:LINE(28,64)-(35,71),3,BF:FOR L=40 TO 240 STEP 40:LINE(L,64)-(L+35,71),3,BF:NEXT:LINE(280,64)-(287,71),3,BF:RETURN
150 LINE(156,4)-(163,11),3,BF:LINE(150,6)-(155,167),0,BF:LINE(164,6)-(169,167),0,BF:FOR L=16 TO 136 STEP 24:LINE(156,L)-(163,L+19),3,BF:NEXT:LINE(156,160)-(163,167),3,BF:RETURN
160 FOR I=1 TO 15:COL=INT(RND(1)*3)+1:GOSUB 126:GOSUB 340:NEXT:COL=2:GOSUB 126:RETURN
170 FOR I=1 TO 15:COL=INT(RND(1)*3)+1:GOSUB 136:GOSUB 340:NEXT:COL=2:GOSUB 136:RETURN
210 GOSUB 5003:LOCATE 25,6:PRINT "DO YOU WANT TO STOP? (Y OR N)";
212 GOSUB 80:IF IN$<>"N" AND IN$<>"Y" THEN 212
214 IF IN$="Y" THEN GOTO 1500
216 GOSUB 5025:RETURN
220 GOSUB 5002:LOCATE 25,6:PRINT "DO YOU WANT TO STOP? (Y OR N)";
222 GOSUB 80:IF IN$<>"N" AND IN$<>"Y" THEN 212
224 IF IN$="Y" THEN GOTO 1500
226 GOSUB 5025:RETURN
230 GOSUB 80:IF IN$<>"T" AND IN$<>"G" AND IN$<>"?" AND IN$<>CHR$(27) THEN 230
232 IF IN$="?" THEN GOSUB 2000:SCREEN 1,0:FG1=1:RETURN
234 IF IN$=CHR$(27) THEN GOSUB 220:FG1=2:RETURN
236 RETURN
250 FOR I=1 TO LEN(C$):B$=MID$(C$,I,1):GOSUB 350:GOSUB 450:NEXT:RETURN
260 FLAG=0:GOSUB 80
262 IF IN$="?" THEN FLAG=1:GOSUB 2000:RETURN
263 IF IN$=CHR$(8) THEN FLAG=3:RETURN
264 IF IN$=CHR$(27) THEN FLAG=2:GOSUB 220:RETURN
266 IF IN$<>"+" AND IN$<>"-" AND IN$<>"1" AND IN$<>"3" AND IN$<>"0" AND IN$<>"2" THEN 260
268 RETURN
270 FLAG=0:GOSUB 80
272 IF IN$="?" THEN FLAG=1:GOSUB 2000:RETURN
274 IF IN$=CHR$(27) THEN FLAG=2:GOSUB 220:RETURN
276 IF IN$<>"1" AND IN$<>"3" AND IN$<>"0" AND IN$<>"2" AND IN$<>CHR$(8) THEN 270
277 IF IN$=CHR$(8) THEN FLAG=3
278 RETURN
300 IF SND=0 THEN GOSUB 465:RETURN ELSE PLAY"O3L8GO4CEL4GL8EL4GL8EL4GL8EO3GO4CEL4GL8EL4GL8EL3C":RETURN
310 IF SND=0 THEN GOSUB 455:RETURN ELSE PLAY"O2L16FL8C":RETURN
320 IF SND=0 THEN GOSUB 450:RETURN ELSE PLAY"O2L48EDCDEDG":RETURN
330 IF SND=0 THEN GOSUB 455:RETURN ELSE PLAY"L16"+P$(L+5):RETURN
340 IF SND=0 THEN GOSUB 455:RETURN ELSE PLAY"L64N"+STR$(INT(RND(1)*84)):RETURN
350 PRINT B$+" ";:IF SND=0 THEN GOSUB 455:RETURN ELSE PLAY"O3L16G":RETURN
400 IF X=Y AND Y<>A THEN X1=X:Y1=Y:A1=0:GOSUB 120:GOSUB 310:RETURN
402 IF X=Y AND Y=A THEN X1=X:Y1=Y:A1=1:GOSUB 120:GOSUB 320:RETURN
404 IF X<=A AND Y>=A THEN X1=X:Y1=Y:A1=1:GOSUB 120:GOSUB 320:RETURN
406 IF Y<=A AND X>=A THEN X1=Y:Y1=X:A1=1:GOSUB 120:GOSUB 320:RETURN
408 IF X<Y THEN X1=X:Y1=Y:A1=0:GOSUB 120:GOSUB 310:RETURN
410 X1=Y:Y1=X:A1=0:GOSUB 120:GOSUB 310:RETURN
420 IF X=Y AND Y<>B THEN X2=X:Y2=Y:A2=0:GOSUB 130:GOSUB 310:RETURN
422 IF X=Y AND Y=B THEN X2=X:Y2=Y:A2=1:GOSUB 130:GOSUB 320:RETURN
424 IF X<=B AND Y>=B THEN X2=X:Y2=Y:A2=1:GOSUB 130:GOSUB 320:RETURN
426 IF Y<=B AND X>=B THEN X2=Y:Y2=X:A2=1:GOSUB 130:GOSUB 320:RETURN
428 IF X<Y THEN X2=X:Y2=Y:A2=0:GOSUB 130:GOSUB 310:RETURN
430 X2=Y:Y2=X:A2=0:GOSUB 130:GOSUB 310:RETURN
450 FOR PAUSE=1 TO 200:NEXT:RETURN
455 FOR PAUSE=1 TO 50:NEXT:RETURN
460 FOR PAUSE=1 TO 500:NEXT:RETURN
465 FOR PAUSE=1 TO 1000:NEXT:RETURN
470 FOR PAUSE=1 TO 2000:NEXT:RETURN
500 P3$=P1$:P4$=P2$:K=INT(RND(1)*10):IF K<5 THEN P2$=P3$:P1$=P4$:RETURN ELSE RETURN
600 I$="":LOCATE 25,2:PRINT "Your guess is ";:GOSUB 260:I$=IN$:IF FLAG=1 THEN RETURN
601 IF FLAG=2 THEN GOSUB 5002:GOTO 600
602 PRINT I$;:IF I$<>"+" AND I$<>"-" THEN X=VAL(I$):Y=X:GOTO 630
610 GOSUB 270:IF FLAG=1 THEN RETURN
611 IF FLAG=2 THEN GOSUB 5002:LOCATE 25,2:PRINT "Your guess is ";I$;:GOTO 610
612 IF IN$=CHR$(8) THEN GOSUB 5025:GOTO 600
614 PRINT IN$;:I$=I$+IN$:X=VAL(I$):Y=X
630 GOSUB 460:RETURN
700 I$="":GOSUB 5002:LOCATE 25,2:PRINT "FROM ";:GOSUB 260:IF FLAG=1 THEN RETURN
701 IF FLAG=2 OR FLAG=3 THEN 700
704 I$=IN$:PRINT I$;:IF I$<>"+" AND I$<>"-" THEN X=VAL(I$):GOTO 730
710 GOSUB 270:IF FLAG=1 THEN RETURN
712 IF FLAG=2 THEN GOSUB 5002:LOCATE 25,2:PRINT "FROM ";I$;:GOTO 710
713 IF FLAG=3 THEN 700
714 PRINT IN$;:I$=I$+IN$:X=VAL(I$)
730 I1$=I$:GOSUB 450:PRINT" TO ";:GOSUB 260
731 IF FLAG=3 THEN 700
732 IF FLAG=1 THEN RETURN
733 IF FLAG=2 THEN GOSUB 5002:LOCATE 25,2:PRINT "FROM ";I1$;:GOTO 730
734 I$=IN$:PRINT I$;:IF IN$<>"+" AND IN$<>"-" THEN Y=VAL(I$):GOTO 750
740 GOSUB 270:IF FLAG=1 THEN RETURN
741 IF FLAG=3 THEN GOSUB 5001:LOCATE 25,2:PRINT "FROM ";I1$;" TO ";:I$="":GOSUB 260:GOTO 731
742 IF FLAG=2 THEN GOSUB 5002:LOCATE 25,2:PRINT "FROM ";I1$;" TO ";I$;:GOTO 740
744 PRINT IN$;:I$=I$+IN$:Y=VAL(I$)
750 GOSUB 450:RETURN
800 SCREEN 0,1:LOCATE 1,1,0:COLOR 7,0:GOSUB 5004:NU=NU+4:IF NU<4 THEN GOSUB 808
802 ON NU GOTO 840,830,820,810,820,830,840
804 FOR I=1 TO 400:NEXT:LOCATE 25,1,0:COLOR 7:RETURN
808 LOCATE 9,9:COLOR 15,0:PRINT STRING$(4,219);:LOCATE 10,9:PRINT STRING$(4,219);:RETURN
810 LOCATE 3,17:COLOR 4:PRINT N5$;:LOCATE 4,16:PRINT LEFT$(N3$,8);:LOCATE 5,15:COLOR 6:PRINT STRING$(3,219);STRING$(4,32);STRING$(3,219);:LOCATE 6,15:PRINT N0$;:COLOR 14:LOCATE 7,15:PRINT N0$;:LOCATE 8,15:PRINT N0$;
812 COLOR 10:LOCATE 9,15:PRINT N0$;:LOCATE 10,15:PRINT N0$;:COLOR 9:LOCATE 11,15:PRINT N0$;:LOCATE 12,15:PRINT N0$;:COLOR 1:LOCATE 13,15:PRINT N0$;
814 LOCATE 14,15:PRINT STRING$(3,219);STRING$(4,32);STRING$(3,219);:COLOR 5:LOCATE 15,16:PRINT LEFT$(N3$,8);:LOCATE 16,17:PRINT N5$;:RETURN
820 COLOR 4:LOCATE 3,19:PRINT N1$;:LOCATE 4,18:PRINT CHR$(219);N1$;:COLOR 6:LOCATE 5,17:PRINT N1$;N1$;:LOCATE 6,16:PRINT CHR$(219);N1$;N1$;:COLOR 14:LOCATE 7,19:PRINT N1$;:LOCATE 8,19:PRINT N1$;
822 COLOR 10:LOCATE 9,19:PRINT N1$;:LOCATE 10,19:PRINT N1$;:COLOR 9:LOCATE 11,19:PRINT N1$;:LOCATE 12,19:PRINT N1$;:COLOR 1:LOCATE 13,19:PRINT N1$;:LOCATE 14,19:PRINT N1$;:COLOR 5:LOCATE 15,17:PRINT N5$;:LOCATE 16,17:PRINT N5$;
824 RETURN
830 COLOR 4:LOCATE 3,17:PRINT STRING$(6,219);:LOCATE 4,16:PRINT STRING$(8,219);:COLOR 6:LOCATE 5,15:PRINT STRING$(3,219);STRING$(4,32);STRING$(3,219);:LOCATE 6,15:PRINT N0$;:COLOR 14:LOCATE 7,23:PRINT N1$;:LOCATE 8,22:PRINT STRING$(3,219);
832 COLOR 10:LOCATE 9,21:PRINT STRING$(3,219);:LOCATE 10,20:PRINT STRING$(3,219);:COLOR 9:LOCATE 11,19:PRINT STRING$(3,219);:LOCATE 12,18:PRINT STRING$(3,219);:COLOR 1:LOCATE 13,17:PRINT STRING$(3,219);:LOCATE 14,16:PRINT STRING$(3,219);
834 COLOR 5:LOCATE 15,15:PRINT STRING$(10,219);:LOCATE 16,15:PRINT STRING$(10,219);:RETURN
840 COLOR 4:LOCATE 3,17:PRINT N5$;:LOCATE 4,16:PRINT LEFT$(N3$,8);:COLOR 6:LOCATE 5,15:PRINT STRING$(3,219);STRING$(4,32);STRING$(3,219);:LOCATE 6,15:PRINT N0$;:COLOR 14:LOCATE 7,23:PRINT N1$;:LOCATE 8,22:PRINT N1$;CHR$(219);:COLOR 10:LOCATE 9,18
842 PRINT N5$;:LOCATE 10,18:PRINT N5$;:COLOR 9:LOCATE 11,22:PRINT STRING$(3,219);:LOCATE 12,23:PRINT N1$;
844 COLOR 1:LOCATE 13,15:PRINT N0$;:LOCATE 14,15:PRINT STRING$(3,219);STRING$(4,32);STRING$(3,219);:COLOR 5:LOCATE 15,16:PRINT LEFT$(N3$,8);:LOCATE 16,17:PRINT N5$;:RETURN
1000 SCREEN 0,1:COLOR 15,0,0:CLS:LOCATE 12,8,0:PRINT"HOW MANY PLAYERS? (1 OR 2)";
1002 GOSUB 80:IF IN$<>"1" AND IN$<>"2" AND IN$<>"?" AND IN$<>CHR$(27) THEN 1002
1004 IF IN$=CHR$(27) THEN GOSUB 210:GOTO 1000
1006 IF IN$="?" THEN GOSUB 2000:GOTO 1000
1008 PL=2:IF IN$="1" THEN PL=1:GOTO 1040
1010 NM$="":GOSUB 5600
1012 IF FIN=1 THEN FIN=0:GOSUB 210:GOTO 1010
1013 IF FIN=2 THEN FIN=0:GOSUB 2000:GOTO 1010
1014 IF NM$="" THEN NM$="PLAYER 1"
1016 P1$=NM$
1020 CLS:LOCATE 11,9:PRINT"Who is the other player?";
1022 GOSUB 5100:LOCATE 14,7:PRINT "NAME <ENTER> ==> ";STRING$(9,176);:LOCATE 14,25:NM$="":GOSUB 5500
1023 IF FIN=1 THEN FIN=0:GOSUB 210:GOTO 1020
1024 IF FIN=2 THEN FIN=0:GOSUB 2000:GOTO 1020
1025 IF NM$="" THEN NM$="PLAYER 2"
1026 IF P1$=NM$ THEN 1030
1027 P2$=NM$:GOTO 1050
1030 CLS:LOCATE 11,3:PRINT"The other player is called ";P1$;:LOCATE 12,6:PRINT"also! Please press <ENTER> and";:LOCATE 13,8:PRINT"give me a different name.";:GOSUB 80:IF IN$<>CHR$(13) THEN 1030
1038 GOTO 1020
1040 NM$="":GOSUB 5600
1042 IF FIN=1 THEN FIN=0:GOSUB 210:GOTO 1040
1043 IF FIN=2 THEN FIN=0:GOSUB 2000:GOTO 1040
1044 IF NM$="" THEN NM$="PLAYER 1"
1046 P1$=NM$
1050 NA=1:IF PL=1 THEN P2$=P1$
1052 CLS:GOSUB 500:SCREEN 1,0:COLOR 0
1056 A=INT(RND(1)*7)-3:B=INT(RND(1)*7)-3:WI=0:T1=0:T2=0:G1=0:G2=0
1060 K=RND(1):IF K<.5 THEN 1200
1100 FLAG=0:GOSUB 100:IF T1=0 THEN TRY1$=" try":GOTO 1110 ELSE TRY1$=" tries"
1102 GOSUB 120
1103 GOSUB 5003:LOCATE 23,2:PRINT P1$+", TRAP OR GUESS? (T OR G)";:GOSUB 230
1104 IF FG1=1 THEN FG1=0:GOTO 1100 ELSE IF FG1=2 THEN FG1=0:GOTO 1103
1105 TRY1$=" tries"
1106 IF IN$<>"T" AND IN$<>"G" THEN 1104
1108 IF IN$="G" THEN 1150
1110 GOSUB 5003:LOCATE 23,2:PRINT "TRAP MY NUMBER, "+P1$;:GOSUB 700:IF FLAG=1 THEN FLAG=0:SCREEN 1,0:GOTO 1100
1112 GOSUB 140:GOSUB 400
1120 C$="You didn't trap my number.":IF X=Y AND X=A THEN C$="You guessed my number in"+STR$(T1+1)+TRY1$+"!":GOTO 1130
1122 IF X=Y THEN 1130
1124 IF X<=A AND A<=Y THEN C$="You trapped my number."
1126 IF Y<=A AND A<=X THEN C$="You trapped my number."
1130 GOSUB 5004:LOCATE 23,2:PRINT C$;:IF X=A AND Y=A THEN P$=P1$:NU=A:GOSUB 160:GOTO 1300
1132 IF C$="You trapped my number." THEN LOCATE 25,2:PRINT "To win, guess my number next turn.";:GOSUB 465
1134 GOSUB 470:GOSUB 465
1140 T1=T1+1:IF PL=1 THEN GOSUB 5004:GOTO 1103
1142 IF PL=2 THEN 1200
1150 GOSUB 5003:LOCATE 23,2:PRINT "What's my number?";:GOSUB 600:IF FLAG=1 THEN FLAG=0:SCREEN 1,0:GOTO 1100
1152 GOSUB 140:GOSUB 400
1154 C$="That isn't it.":IF X=A THEN C$="You guessed my number in"+STR$(T1+1)+TRY1$+"!"
1156 GOSUB 5003:LOCATE 24,2:PRINT C$;:IF X=A THEN NU=A:P$=P1$:GOSUB 160:GOTO 1300
1160 GOSUB 470:GOSUB 465
1170 T1=T1+1:IF PL=1 THEN GOSUB 5004:GOTO 1103
1200 FLAG=0:GOSUB 110:IF T2=0 THEN TRY2$=" try":GOTO 1210 ELSE TRY2$=" tries"
1202 GOSUB 130
1203 GOSUB 5003:LOCATE 23,2:PRINT P2$+", TRAP OR GUESS? (T OR G)";:GOSUB 230
1204 IF FG1=1 THEN FG1=0:GOTO 1200 ELSE IF FG1=2 THEN FG1=0:GOTO 1203
1205 TRY2$=" tries"
1206 IF IN$<>"T" AND IN$<>"G" THEN 1204
1208 IF IN$="G" THEN 1250
1210 GOSUB 5003:LOCATE 23,2:PRINT "TRAP MY NUMBER, "+P2$;:GOSUB 700:IF FLAG=1 THEN FLAG=0:SCREEN 1,0:GOTO 1200
1212 GOSUB 150:GOSUB 420
1220 C$="You didn't trap my number.":IF X=Y AND Y=B THEN C$="You guessed my number in"+STR$(T2+1)+TRY2$+"!":GOTO 1230
1222 IF X=Y THEN 1230
1224 IF X<=B AND B<=Y THEN C$="You trapped my number."
1226 IF Y<=B AND B<=X THEN C$="You trapped my number."
1230 GOSUB 5003:LOCATE 23,2:PRINT C$;:IF X=Y AND Y=B THEN P$=P2$:NU=B:GOSUB 170:GOTO 1300
1232 IF C$="You trapped my number." THEN LOCATE 25,2:PRINT "To win, guess my number next turn.";:GOSUB 460
1234 GOSUB 470:GOSUB 465
1240 T2=T2+1:IF PL=1 THEN GOSUB 5004:GOTO 1203
1242 GOTO 1100
1250 GOSUB 5003:LOCATE 23,2:PRINT "What's my number?";:GOSUB 600:IF FLAG=1 THEN FLAG=0:SCREEN 1,0:GOTO 1200
1252 GOSUB 150:GOSUB 420
1254 C$="That isn't it.":IF X=B THEN C$="You guessed my number in"+STR$(T2+1)+TRY2$+"!"
1256 GOSUB 5004:LOCATE 23,2:PRINT C$;:IF X=B THEN NU=B:P$=P2$:GOSUB 170:GOTO 1300
1260 GOSUB 470:GOSUB 465
1270 T2=T2+1:IF PL=1 THEN GOSUB 5004:GOTO 1203
1272 GOTO 1100
1300 GOSUB 465:GOSUB 800:COLOR 15,0
1305 GOSUB 300
1307 DEF SEG=&HF000:PC=PEEK(&HFFFE):DEF SEG:IF PC=&HFD THEN GOSUB 470:GOSUB 470
1310 GOSUB 5004:LOCATE 23,11,0:PRINT "Play again? (Y or N)";
1311 GOSUB 80:IF IN$<>"?" AND IN$<>"N" AND IN$<>"Y" THEN 1311
1312 IF IN$="Y" AND PL=1 THEN 1050
1314 IF IN$="Y" AND PL=2 THEN 1052
1315 IF IN$="?" THEN GOSUB 2000:CLS:GOTO 1310
1320 GOSUB 5004:LOCATE 23,5,0:PRINT "Would anyone else like to play?";:LOCATE 24,17,0:PRINT "(Y or N)";
1322 GOSUB 80:IF IN$<>"Y" AND IN$<>"N" AND IN$<>"?" THEN 1322
1324 IF IN$="Y" THEN CLS:GOTO 60
1325 IF IN$="?" THEN GOSUB 2000:CLS:GOTO 1320
1326 GOSUB 5004:LOCATE 23,2:PRINT "Goodbye! It was fun playing with you!";
1500 RUN"menu
2000 SCREEN 0,1:CLS:COLOR 13:LOCATE 1,1,0:PRINT STRING$(40,176);:FOR L=2 TO 22:LOCATE L,1:PRINT CHR$(176);:LOCATE L,40:PRINT CHR$(176);:NEXT:LOCATE 23,1:PRINT STRING$(40,176);
2002 INS$(1)="Is Bumble's secret number":INS$(2)="-3, -2, -1, 0, 1, 2, or 3?":INS$(3)="To find out, first TRAP it":INS$(4)="between two numbers.  Then":INS$(5)="try to GUESS the number."
2004 INS$(6)="For two players, each will":INS$(7)="have a special number.":LL=1:COLOR 15
2010 FOR L=5 TO 7 STEP 2:GOSUB 2100:LOCATE L,LE:PRINT INS$(LL);:LL=LL+1:NEXT:FOR L=10 TO 14 STEP 2:GOSUB 2100:LOCATE L,LE:PRINT INS$(LL);:LL=LL+1:NEXT:FOR L=17 TO 19 STEP 2:GOSUB 2100:LOCATE L,LE:PRINT INS$(LL);:LL=LL+1:NEXT
2052 GOSUB 470
2054 LOCATE 22,10:PRINT "PRESS <ENTER> TO PLAY";
2056 GOSUB 80:IF IN$<>CHR$(27) AND IN$<>CHR$(13) THEN 2056
2058 IF IN$=CHR$(27) THEN LOCATE 22,6:PRINT "DO YOU WANT TO STOP? (Y OR N)";:GOTO 2059 ELSE IF IN$=CHR$(13) THEN 2060
2059 GOSUB 80:IF IN$<>"Y" AND IN$<>"N" THEN 2059 ELSE IF IN$="Y" THEN CLS:GOTO 1500 ELSE LOCATE 22,6:PRINT STRING$(30,32);:GOTO 2054
2060 RETURN
2100 LE=INT((40-LEN(INS$(LL)))/2)+1:RETURN
3000 IF INKEY$=" " THEN RETURN ELSE GOSUB 100:GOSUB 460
3002 IF INKEY$=" " THEN RETURN
3010 C$="TRAP":LOCATE 23,6:GOSUB 250:A1=1:X1=0:Y1=3:GOSUB 120:GOSUB 320:GOSUB 465
3011 IF INKEY$=" " THEN RETURN
3012 LOCATE 23,16:C$="AND":GOSUB 250:GOSUB 140:X1=1:Y1=2:GOSUB 120:GOSUB 320:GOSUB 460
3013 IF INKEY$=" " THEN RETURN
3014 LOCATE 23,24:C$="GUESS!":GOSUB 250:GOSUB 140:X1=2:Y1=2:GOSUB 120:GOSUB 320:GOSUB 460
3016 IF INKEY$=" " THEN RETURN
3020 GOSUB 5023:LOCATE 23,13:PRINT "IT'S A TWO!";:GOSUB 160:GOSUB 460:RETURN
5001 LOCATE 25,1:PRINT STRING$(39,32);:RETURN
5002 LOCATE 24,1:PRINT STRING$(39,32);:LOCATE 25,1:PRINT STRING$(39,32);:RETURN
5003 FOR L=23 TO 25:LOCATE L,1:PRINT STRING$(39,32);:NEXT:RETURN
5004 FOR L=22 TO 25:LOCATE L,1:PRINT STRING$(39,32);:NEXT:RETURN
5005 FOR L=21 TO 24:LOCATE L,1:PRINT STRING$(39,32);:NEXT:LOCATE 25,1:PRINT STRING$(38,32);:RETURN
5022 LOCATE 22,1:PRINT STRING$(40,32);:RETURN
5023 LOCATE 23,1:PRINT STRING$(40,32);:RETURN
5024 LOCATE 24,1:PRINT STRING$(39,32);:RETURN
5025 LOCATE 25,1:PRINT STRING$(39,32);:RETURN
5100 DEF SEG=0:RAND=RND(0):POKE 1047,(PEEK(1047) OR 96) AND (223-(32*(PC<>&HFD))):DEF SEG:RETURN
5102 DEF SEG=0:POKE 1047,96+32*(PC=&HFD):DEF SEG:RETURN
5110 DEF SEG=0:POKE 1050,PEEK(1052):DEF SEG:RETURN
5400 DEF SEG=0:SND=PEEK(1264):DEF SEG=&HF000:IF PEEK(&HFFFE)=&HFD THEN PC=&HFD
5401 DEF SEG:RETURN
5500 GOSUB 80:IF IN$=CHR$(13) THEN RETURN
5510 IF IN$=CHR$(8) THEN LOCATE 14,24:PRINT STRING$(LEN(NM$),176);:IF NM$="" THEN 5500 ELSE NM$=LEFT$(NM$,LEN(NM$)-1):LOCATE 14,24:PRINT NM$;:GOTO 5500
5520 IF IN$=CHR$(27) THEN FIN=1:RETURN
5530 IF IN$="?" THEN FIN=2:RETURN
5540 NM$=NM$+IN$:LOCATE 14,24:PRINT NM$
5550 IF LEN(NM$)<9 THEN 5500 ELSE RETURN
5600 GOSUB 5100:CLS:LOCATE 11,10,0:PRINT "Please type your name.":LOCATE 12,12:PRINT "(up to 9 letters)";:LOCATE 14,7:PRINT "NAME <ENTER> ==> ";STRING$(9,176);:LOCATE 14,24:GOSUB 5500:RETURN
9000 DATA BR4R3F4D11G4L3H4U11E4D4E1R1F2D9G2L1H2U9E2,BR4R3D16R4D3L11U3R4U11L4U1E4,BR4R3F4D5G6D1R6D3L11U4E8U2H2L1G2L3U1E4,BR4R3F4D3G2D1F2D3G4L3H4U1R3F2R1E2U2H2U1E2U2H2L1G2L3U1E4
9004 DATA O2C,O2D,O2E,O2F,O2G,O2A,O2B,O3C
9999 RUN