10 ON ERROR GOTO 9999:GOSUB 5400
20 RANDOMIZE TIMER:DIM X(20),Y(20),DT(6),SA(4),L(12),EX(4),N$(20),A(20),B(20):FOR L=0 TO 19:READ N$(L):NEXT:FOR L=0 TO 20:X(L)=80+L*8:Y(L)=150-L*7:NEXT:E$="Type X,Y <ENTER>: "
22 PRE$="Press <ENTER> to choose a picture.":SCREEN 1,0:COLOR 0,1:CLS:GOSUB 8000:CLS:GOSUB 2000:GOSUB 5000
24 LOCATE 23,2:PRINT"Would you like instructions? (Y or N)";
32 GOSUB 60:IF IN$><"Y" AND IN$<>"N" AND IN$<>CHR$(27) THEN 32
34 IF IN$="N" THEN 50 ELSE IF IN$="Y" THEN GOSUB 4000:GOTO 1014
40 SCREEN 0,1:COLOR 15,1,1:CLS:LOCATE 12,1,0:PRINT"Do you want to stop this game? (Y or N)";
42 GOSUB 60:IF IN$<>"Y" AND IN$<>"N" THEN 42
44 IF IN$="Y" THEN 1500 ELSE SCREEN 1,0:GOTO 24
50 GOTO 1000
60 GOSUB 5100:IN$=INKEY$:IF IN$="" OR IN$=CHR$(9) THEN 60 ELSE IF LEN(IN$)<>1 THEN GOSUB 5102:GOTO 60 ELSE GOSUB 5102:RETURN
100 FLAG=0:ER=0
102 N1=N1+10:N2=N2+10:IF X(N1)=A(P) AND Y(N2)=B(P) THEN RETURN
110 GET(X(N1)-4,Y(N2)-4)-(X(N1)+3,Y(N2)+3),SA:PUT(X(N1)-4,Y(N2)-4),EX,OR:FLAG=1:ER=1:GOSUB 410
111 IF X(N2)=A(P) AND Y(N1)=B(P) THEN 170
112 IF X(N1)=A(P) THEN 160
113 IF Y(N2)<>B(P) THEN 130
114 IF X(20-N1)=A(P) THEN C$="You need to change the sign of X.":GOTO 178
116 IF X(N1)>A(P) THEN C$="Try a smaller value for X.":GOTO 178
118 C$="Try a larger value for X.":GOTO 178
130 IF X(20-N1)=A(P) AND Y(20-N2)=B(P) THEN C$="Change the signs of X and Y.":GOTO 178
132 IF X(20-N1)=A(P) THEN 142
134 IF Y(20-N2)=B(P) THEN 152
136 CX$=" bigger ":IF X(N1)>A(P) THEN CX$=" smaller "
138 CY$=" smaller ":IF Y(N2)>B(P) THEN CY$=" bigger "
140 C$="Try a"+CX$+"X and a"+CY$+"Y.":GOTO 178
142 CY$=" make Y bigger.":IF Y(N2)<B(P) THEN CY$=" make Y smaller."
144 C$="Change the sign of X and"+CY$:GOTO 178
152 CX$="Make X smaller ":IF X(N1)<A(P) THEN CX$="Make X bigger "
154 C$=CX$+"and change the sign of Y.":GOTO 178
160 IF Y(20-N2)=B(P) THEN C$="You need to change the sign of Y.:goto 178
162 IF Y(N2)>B(P) THEN C$="Try a larger value for Y.":GOTO 178
164 C$="Try a smaller value for Y.":GOTO 178
170 C$="Please switch your X and Y.":GOTO 178
178 LOCATE 22,2:PRINT STRING$(39,32);:LOCATE 22,2:PRINT C$;:RETURN
300 FOR L=-1 TO 1:LINE(A(P)-L,B(P))-(A(P-1)-L,B(P-1)),CU-1:NEXT:IF B(P)=B(P-1) THEN LINE(A(P),B(P)-1)-(A(P-1),B(P-1)-1),CU-1:RETURN ELSE RETURN
302 P1=0:FOR I=1 TO P:FOR L=-1 TO 1:LINE(A(P1)-L,B(P1))-(A(I)-L,B(I)),CU-1:NEXT:P1=P1+1:NEXT:RETURN
310 FOR L=1 TO 2:CIRCLE(A(P),B(P)),L,2:NEXT:RETURN
404 IF SND=0 THEN RETURN ELSE PLAY "O3L16"+N$(P):RETURN
410 IF SND=1 THEN PLAY"O3L16FL8C":RETURN ELSE GOSUB 730:RETURN
420 IF SND=0 THEN GOSUB 740:RETURN ELSE PLAY"T185O4L8CO3BO4L4CO3CCL8GFEGO4CO3BO4CEDCL4DO3DDL8DCO2BO3DL4GGL8ABO4CO3BAGAGFEFEDCDCO2BAGABO3CDEFDL4ECL2CT120":RETURN
430 IF SND=0 THEN GOSUB 740 ELSE PLAY"O2L12GFECCO1GO2CCECEGFEFDDO1GO2DDFDFAGFECCO1GO2CCECEGFEFEFDGFECCL4C":RETURN
440 IF SND=0 THEN GOSUB 740 ELSE PLAY"T150O2L8DD#EL4O3CO2L8EO3L4CO2L8EO3MLL2CMNL4CL8CDD#ECDL4EO2L8BO3L4DMLL2CMNL4CL8CDECDL4EL8CDCECDL4EL8CDCECDL4EL8O2BL4O3DMLL2CMNL4CT120":RETURN
450 IF SND=0 THEN GOSUB 740:RETURN ELSE PLAY"T180O3L3CL8DL4CAGFO2L2AL4O3DMLL2CMNL4CCO2GAB-DEMLL2FMNL4FMLL2AMNL4AO3L3CL8DL4CAGFO2L2AL4O3DMLL2CMNL4CCO2GAB-DEL2FL4AL2FT120":RETURN
460 IF SND=0 THEN GOSUB 740:RETURN ELSE PLAY"T95O3L12EL6GL12ECO2BO3CDDO2BL6GO3L12GL6AL12GFEDL4G.P32L24EFL6GL12ECO2BO3CDDO2BL6GO3L12GL6AL12GFEDL4C.T120":RETURN
470 IF SND=0 THEN GOSUB 740:RETURN ELSE FOR TUNE=1 TO 2:PLAY"T100O3L8CCGGAAL4GL8FFEEDDL4CT120":NEXT:RETURN
480 IF SND=0 THEN GOSUB 740:RETURN ELSE PLAY"t100O3L12Cco2aO3L4co2L6b-L12AL4gL12agffefl6gl12al4go3l12cco2ao3l4fl6dl12o2b-l4gl12ab-o3co2b-agl2f":RETURN
500 SCREEN 1,0:COLOR 8,1:CLS:LINE(80,10)-(240,150),1,B:LINE(160,10)-(161,150),1,B:LINE(80,80)-(240,80),1:FOR L=80 TO 240 STEP 8:LINE(L,76)-(L+1,84),1,B:NEXT:FOR L=10 TO 150 STEP 7:LINE(156,L)-(165,L),1:NEXT
502 LINE(120,10)-(121,150),1,B:LINE(200,10)-(201,150),1,B:LINE(80,45)-(240,45),1:LINE(80,115)-(240,115),1:LINE(81,10)-(241,150),1,B
504 LOCATE 2,20:PRINT "+10";:LOCATE 11,21:PRINT "0";
506 LOCATE 11,8:PRINT "-10";:LOCATE 11,15:PRINT "-5";:LOCATE 11,25:PRINT "+5";:LOCATE 11,31:PRINT "+10";
508 LOCATE 1,1:PRINT "+5";:GET(0,0)-(15,7),L:PUT(152,43),L,PSET:LOCATE 1,1:PRINT "-5";:GET(0,0)-(15,7),L:PUT(152,113),L,PSET:LOCATE 1,1:PRINT "-10";:GET(0,0)-(23,7),L:PUT(152,148),L,PSET:LOCATE 1,1:PRINT "   ";
510 LOCATE 9,5:PRINT CHR$(24);:LOCATE 11,5:PRINT "Y";:LOCATE 13,5:PRINT CHR$(25);:LOCATE 21,19:PRINT CHR$(27);:LOCATE 21,21:PRINT "X";:LOCATE 21,23:PRINT CHR$(26);:LOCATE 3,33:PRINT "X , Y";:RETURN
600 C$="":B$="":LOCATE 23,2:PRINT E$;:GOSUB 830:IF ASC(IN$)=13 OR IN$="," THEN 600 ELSE IF EFLAG=1 THEN GOSUB 670:GOTO 600 ELSE IF EFLAG=2 OR EFLAG=3 THEN RETURN
601 IF IN$=CHR$(8) THEN 600
602 B$=IN$:PRINT B$;:IF IN$<>"+" AND IN$<>"-" THEN 610
604 GOSUB 830:IF EFLAG=1 THEN GOSUB 670:GOTO 604 ELSE IF EFLAG=2 OR EFLAG=3 THEN RETURN
605 IF IN$=CHR$(8) THEN GOSUB 680:GOTO 600
606 IF IN$<"0" OR IN$>"9" THEN 604
608 B$=B$+IN$:PRINT IN$;
610 IF ABS(VAL(B$))<>1 THEN N3=VAL(B$):GOTO 620
612 GOSUB 830:IF EFLAG=1 THEN GOSUB 670:GOTO 612 ELSE IF EFLAG=2 OR EFLAG=3 THEN RETURN
613 IF IN$=CHR$(8) THEN GOSUB 680:GOTO 600
614 IF IN$="0" THEN PRINT IN$;:B$=B$+IN$:N3=VAL(B$):GOTO 620
615 IF IN$="," THEN N3=VAL(B$):GOTO 624
616 IF IN$=CHR$(8) THEN GOSUB 680:GOTO 600
617 GOTO 612
620 GOSUB 830:IF EFLAG=1 THEN GOSUB 670:GOTO 620 ELSE IF EFLAG=2 OR EFLAG=3 THEN RETURN
621 IF IN$=CHR$(8) THEN GOSUB 680:GOTO 600
622 IF IN$<>"," THEN CP=POS(1):LOCATE 25,2:PRINT "There must be a comma between X and Y.";:LOCATE 23,CP:GOTO 620
624 PRINT IN$;:B$=B$+IN$:GOSUB 5020
630 B1$="":GOSUB 830:IF EFLAG=1 OR IN$="," OR ASC(IN$)=13 THEN GOSUB 670:GOTO 630 ELSE IF EFLAG=2 OR EFLAG=3 THEN RETURN ELSE IF IN$=CHR$(8) THEN GOSUB 680:GOTO 600
632 B$=B$+IN$:PRINT IN$;:B1$=IN$:IF IN$<>"-" AND IN$<>"+" THEN 640
634 GOSUB 830:IF EFLAG=1 THEN GOSUB 670:GOTO 634 ELSE IF EFLAG=2 OR EFLAG=3 THEN RETURN ELSE IF IN$=CHR$(8) THEN B$=LEFT$(B$,LEN(B$)-1):GOSUB 670:GOTO 630
636 IF IN$<"0" OR IN$>"9" THEN 634
638 B1$=B1$+IN$:B$=B$+IN$:PRINT IN$;
640 IF ABS(VAL(B1$))<>1 THEN N4=VAL(B1$):GOTO 650
641 IF IN$=CHR$(8) THEN 600 ELSE IF EFLAG=2 THEN RETURN
642 GOSUB 830:IF EFLAG=1 THEN GOSUB 670:GOTO 642 ELSE IF EFLAG=2 OR EFLAG=3 THEN RETURN
643 IF ASC(IN$)=13 THEN N4=VAL(B1$):GOTO 652
644 IF IN$=CHR$(8) THEN GOSUB 5000:B$=LEFT$(B$,LEN(B$)-LEN(B1$)):GOSUB 670:GOTO 630
645 IF IN$<>"0" THEN 642
646 B1$=B1$+IN$:PRINT IN$;:B$=B$+IN$:N4=VAL(B1$)
650 GOSUB 830:IF EFLAG=1 THEN GOSUB 670:GOTO 650 ELSE IF EFLAG=2 OR EFLAG=3 THEN RETURN ELSE IF IN$=CHR$(8) THEN B$=LEFT$(B$,LEN(B$)-LEN(B1$)):GOSUB 670:GOTO 630
652 IF IN$<>CHR$(13) THEN 650 ELSE LOCATE 23,2:PRINT STRING$(39,32);
660 LOCATE 22,2:PRINT STRING$(39,32);:IF FLAG=1 THEN PUT(X(N1)-4,Y(N2)-4),SA,PSET
662 N1=N3:N2=N4
664 B1$=B$:LOCATE 5,32:PRINT"   ,   ";:IF LEFT$(B$,2)="10" THEN PX=33 ELSE IF LEFT$(B$,3)="+10" OR LEFT$(B$,3)="-10" THEN PX=32 ELSE IF LEFT$(B$,1)="+" OR LEFT$(B$,1)="-" THEN PX=33 ELSE PX=34
665 LOCATE 5,PX:PRINT B$;:RETURN
670 LOCATE 23,19:PRINT "        ";::LOCATE 22,2:PRINT C$;:LOCATE 23,2:PRINT E$+B$;:RETURN
680 LOCATE 23,19:PRINT "        ";:RETURN
700 IF SND=1 THEN PLAY"O3L16"+N$(P)
702 GOSUB 3000:FOR I=1 TO 10:GOSUB 3000:FOR J=1 TO 30:NEXT J,I:RETURN
710 FOR I=1 TO 2000:NEXT:RETURN
720 FOR I=1 TO 3000:NEXT:RETURN
730 FOR I=1 TO 200:NEXT:RETURN
740 FOR PAUSE=1 TO 1000:NEXT:RETURN
800 FLAG=0:GOSUB 60:IF IN$=CHR$(27) THEN GOSUB 810:RETURN ELSE IF IN$="?" THEN FLAG=2:GOSUB 4000:RETURN ELSE RETURN
810 LOCATE 22,2:PRINT STRING$(39,32);:GOSUB 5000:LOCATE 23,5:PRINT"TYPE  1  TO STOP";:LOCATE 24,11:PRINT"2  TO CHANGE PICTURES";:IF EFLAG<>2 THEN LOCATE 25,11:PRINT "3  TO CONTINUE";
812 GOSUB 60:IF IN$="?" THEN EFLAG=2:SCREEN 1,0:GOSUB 4000:GOTO 810
814 IF IN$<"1" OR IN$>"3" THEN 810
816 IF IN$="1" THEN 1500
818 IF IN$="2" THEN EFLAG=3:GOSUB 5000:RETURN
819 IF IN$="3" AND EFLAG<>2 THEN GOSUB 5000:RETURN ELSE 810
820 IN$=CHR$(13):GOSUB 5210:GOSUB 5010:RETURN
830 EFLAG=0:GOSUB 60:IF IN$=CHR$(13) OR IN$="," OR IN$="+" OR IN$="-" THEN RETURN
831 IF IN$="X" AND B$="" THEN CP=POS(1):LOCATE 25,2:PRINT "Type a NUMBER for X.";STRING$(18,32);:LOCATE 23,CP:GOTO 830
832 IF IN$="Y" AND B$<>"" THEN CP=POS(1):LOCATE 25,2:PRINT "Type a NUMBER for Y.";STRING$(18,32);:LOCATE 23,CP:GOTO 830
833 IF IN$="?" THEN GOSUB 4000:EFLAG=2:IN$=" ":RETURN
834 IF IN$=CHR$(27) THEN EFLAG=1:GOSUB 810:IN$=" ":RETURN
836 IF IN$=CHR$(8) THEN RETURN
837 IF IN$=CHR$(32) THEN GOSUB 700:GOSUB 700:GOTO 830
838 IF IN$<"0" OR IN$>"9" THEN 830 ELSE RETURN
839 GOSUB 5020:RETURN
900 FOR I=1 TO 22:A(I)=0:B(I)=0:NEXT:RETURN
910 A(0)=168:A(1)=192:A(2)=184:A(3)=168:A(4)=168:A(5)=136:A(6)=136:A(7)=152:A(8)=168:B(0)=136:B(1)=101:B(2)=150:B(3)=150:B(4)=87:B(5)=73:B(6)=24:B(7)=38:B(8)=31:A(9)=184:A(10)=200:A(11)=200:A(12)=168
912 B(9)=38:B(10)=24:B(11)=73:B(12)=87:PN=12:RETURN
920 A(0)=144:A(1)=144:A(2)=128:A(3)=112:A(4)=96:A(5)=96:A(6)=120:A(7)=144:A(8)=176:A(9)=216:A(10)=224:A(11)=232:A(12)=232:A(13)=224:A(14)=216:A(15)=168:A(16)=152
922 B(0)=87:B(1)=122:B(2)=143:B(3)=143:B(4)=115:B(5)=59:B(6)=38:B(7)=38:B(8)=66:B(9)=80:B(10)=73:B(11)=80:B(12)=94:B(13)=101:B(14)=115:B(15)=129:B(16)=150:PN=16:RETURN
930 A(0)=176:A(1)=176:A(2)=184:A(3)=176:A(4)=184:A(5)=176:A(6)=168:A(7)=152:A(8)=144:A(9)=152:A(10)=168:A(11)=144:A(12)=128:A(13)=136:A(14)=160:A(15)=160:A(16)=152:A(17)=144:A(18)=144
932 B(0)=150:B(1)=115:B(2)=87:B(3)=59:B(4)=38:B(5)=24:B(6)=24:B(7)=31:B(8)=45:B(9)=52:B(10)=59:B(11)=66:B(12)=94:B(13)=108:B(14)=115:B(15)=143:B(16)=143:B(17)=136:B(18)=150:PN=18:RETURN
940 A(0)=176:A(1)=184:A(2)=128:A(3)=112:A(4)=88:A(5)=80:A(6)=104:A(7)=128:A(8)=136:A(9)=176:A(10)=192:A(11)=224:A(12)=224:A(13)=192:A(14)=176:A(15)=136:A(16)=136:A(17)=192:PN=17
942 B(0)=38:B(1)=31:B(2)=17:B(3)=87:B(4)=101:B(5)=136:B(6)=115:B(7)=115:B(8)=136:B(9)=136:B(10)=115:B(11)=115:B(12)=94:B(13)=87:B(14)=38:B(15)=38:B(16)=87:B(17)=87:RETURN
944 A(5)=118:A(6)=174:A(7)=188:A(8)=146:A(9)=174:A(10)=188:A(11)=216:B(5)=144:B(6)=144:B(7)=102:B(8)=18:B(9)=32:B(10)=18:B(11)=46:P=11:RETURN
950 A(0)=144:A(1)=176:A(2)=200:A(3)=216:A(4)=224:A(5)=224:A(6)=216:A(7)=200:A(8)=176:A(9)=144:A(10)=120:A(11)=104:A(12)=96:A(13)=96:A(14)=104:A(15)=120:A(16)=144:PN=16
952 B(0)=24:B(1)=24:B(2)=38:B(3)=52:B(4)=73:B(5)=94:B(6)=115:B(7)=129:B(8)=143:B(9)=143:B(10)=129:B(11)=115:B(12)=94:B(13)=73:B(14)=52:B(15)=38:B(16)=24:RETURN
954 A(7)=216:A(8)=188:A(9)=188:B(7)=18:B(8)=18:B(9)=39:P=9:RETURN
960 A(0)=144:A(1)=96:A(2)=120:A(3)=160:A(4)=200:A(5)=224:A(6)=144:A(7)=136:A(8)=184:A(9)=176:B(0)=94:B(1)=94:B(2)=59:B(3)=45:B(4)=59:B(5)=94:B(6)=94:B(7)=143:B(8)=143:B(9)=94:PN=9:RETURN
980 A(0)=160:A(1)=208:A(2)=112:A(3)=208:A(4)=112:A(5)=160:B(0)=31:B(1)=122:B(2)=59:B(3)=59:B(4)=122:B(5)=31:PN=5:RETURN
1000 NM$="":FLAG=0:ER=0:P=0:CU=3
1002 FOR I=1 TO 15:A(I)=0:B(I)=0:NEXT
1010 GOSUB 5000:CHOICE=0:LOCATE 23,2:PRINT"1. BUMBLE'S PICTURES  2. MAKE YOUR OWN";:LOCATE 25,3:PRINT"Pick a number or press <ESC> to stop.";
1014 NM$="":FLAG=0:ER=0:P=0:CU=3:GOSUB 60:IF IN$=CHR$(27) THEN GOSUB 4070:GOTO 1000
1016 IF IN$="?" THEN GOSUB 4000:GOTO 1014
1018 CHOICE=VAL(IN$)
1020 IF IN$="2" THEN 1200
1022 IF IN$<>"1" THEN 1014
1024 IF INST=0 THEN GOSUB 5000:LOCATE 23,2:PRINT PRE$; ELSE IF INST=1 THEN INST=0:LOCATE 20,2:PRINT STRING$(38,32);:LOCATE 22,2:PRINT STRING$(38,32);:LOCATE 21,4:PRINT PRE$;
1026 GOSUB 60:IF IN$=CHR$(27) THEN GOSUB 4070:GOTO 1050 ELSE IF IN$="?" THEN GOSUB 4000:GOTO 1014
1028 IF IN$<>CHR$(13) THEN 1026
1050 SCREEN 0,1:COLOR 15,1,1:CLS:LOCATE 4,7,0:PRINT"Bumble's Favorite Pictures:";:LOCATE 7,9:PRINT"1. STAR        ( 6 DOTS)";:LOCATE 9,9:PRINT"2. MUSHROOM    (10 DOTS)";:LOCATE 11,9:PRINT "3. TULIP       (13 DOTS)";
1052 LOCATE 13,9:PRINT "4. BEAGLE      (17 DOTS)";:LOCATE 15,9:PRINT "5. HAPPY       (17 DOTS)";:LOCATE 17,9:PRINT "6. AUTO        (18 DOTS)";:LOCATE 19,9:PRINT "7. BUMBLE      (18 DOTS)";
1070 LOCATE 22,7:PRINT"Type a number to play.";:LOCATE 24,7:PRINT "Press <ESC> to stop.";
1072 GOSUB 60:IF IN$=CHR$(27) THEN GOSUB 4070:GOTO 1050
1074 IF IN$="?" THEN GOSUB 4000:GOTO 1014
1076 IF IN$<"1" OR IN$>"7" THEN 1072
1078 PRINT IN$;
1080 PIC = VAL(IN$):ON PIC GOSUB 980,960,910,920,950,940,930:GOSUB 500
1100 GOSUB 5000:IF P>PN THEN 1268 ELSE GOSUB 700
1102 GOSUB 5010:GOSUB 600:IF EFLAG=3 THEN GOSUB 5000:GOTO 1000 ELSE IF EFLAG=2 THEN 1014 ELSE GOSUB 100:IF ER=1 THEN 1102
1110 GOSUB 3000:IF P>0 THEN 1120
1112 GOSUB 310
1116 P=P+1:GOTO 1100
1120 CU=3:GOSUB 300
1122 P=P+1:IF P>PN THEN 1300
1130 GOTO 1100
1200 CLS:GOSUB 500
1201 C$=""
1202 LOCATE 23,2:PRINT"Name up to 20 dots to make a picture.":LOCATE 25,2:PRINT "Press <ENTER> to begin.";
1204 GOSUB 60:IF IN$=CHR$(27) THEN GOSUB 4070:SCREEN 0,1:GOTO 1000 ELSE IF IN$="?" THEN GOSUB 4000:GOTO 1014
1206 IF IN$<>CHR$(13) THEN 1204
1208 GOSUB 5000
1210 GOSUB 5005:LOCATE 22,2:PRINT"NAME DOT #"+STR$(P+1):GOSUB 600
1211 IF EFLAG=2 THEN EFLAG=0:GOTO 1014 ELSE IF EFLAG=3 THEN 1000
1212 N1=N1+10:N2=N2+10:A(P)=X(N1):B(P)=Y(N2):GOSUB 3000:GOSUB 404
1220 GOSUB 5005:LOCATE 23,2:PRINT"OKAY? (Y OR N)";
1222 GOSUB 800:IF EFLAG=3 THEN 1000
1223 IF IN$<>"Y" AND IN$<>"N" THEN 1220
1224 GOSUB 3000:IF IN$="N" THEN 1210
1226 IF P>0 THEN CU=3:GOSUB 300
1228 IF P=0 THEN GOSUB 310
1230 P=P+1:IF P=20 THEN 1250
1232 GOSUB 5005:LOCATE 23,2:PRINT "Any more dots? (Y or N)";
1234 GOSUB 60:IF IN$=CHR$(27) THEN GOSUB 810:IF EFLAG=3 THEN 1000 ELSE 1232
1236 IF IN$="Y" THEN 1210
1238 IF IN$<>"N" THEN 1234
1250 PN=P:GOSUB 5005:LOCATE 23,2:PRINT"Please choose a name. (1 to 10 letters)";:LOCATE 24,2:PRINT"NAME <ENTER>?";
1252 EFLAG7=0:GOSUB 7100:IF EFLAG7=1 THEN NM$="":GOSUB 810:IF EFLAG=3 THEN 1000 ELSE GOTO 1250
1254 IF LEN(NM$)>10 THEN NM$=LEFT$(NM$,10)
1260 GOSUB 5000:LOCATE 24,2:PRINT"1. Have a friend draw your picture.";:LOCATE 25,2:PRINT"2. Color your picture.";:LOCATE 22,2:PRINT"Choose 1 or 2:";
1262 GOSUB 800:IF FLAG=2 THEN GOTO 1014
1264 IF IN$="1" THEN GOSUB 5000:GOTO 1270
1266 IF IN$<>"2" THEN 1260
1267 LOCATE 22,2:PRINT"               "
1268 GOSUB 5000:PIC=8:GOTO 1300
1270 PIC=8:P=0:PN=PN-1
1271 LOCATE 22,2:PRINT"               "
1272 CLS:GOSUB 500
1274 GOTO 1100
1300 GOSUB 5005:CU=4:ON PIC GOTO 1302,1310,1320,1330,1340,1350,1380,1400
1302 LOCATE 23,16:PRINT "<< STAR >>";:GOSUB 740:GOSUB 740:LINE(0,0)-(319,167),0,BF:P=P-1:GOSUB 302:PAINT(160,72),3,3:PAINT(188,64),3,3
1304 PAINT(132,64),3,3:PAINT(160,48),3,3:PAINT(136,92),3,3:PAINT(180,92),3,3:GOSUB 470:GOSUB 710:GOTO 1000
1310 LOCATE 23,14:PRINT "<< MUSHROOM >>";:GOSUB 740:GOSUB 740:LINE(0,0)-(319,167),0,BF:COLOR 10:P=P-1:GOSUB 302:PAINT(160,68),3,3:PAINT(160,120),2,3:GOSUB 480:GOSUB 710:GOSUB 710:GOTO 1000
1320 LOCATE 23,15:PRINT "<< TULIP >>";:GOSUB 740:GOSUB 740:LINE(0,0)-(319,167),0,BF:COLOR 9:P=P-1:CU=2:GOSUB 302:PAINT(168,52),2,1:PAINT(176,140),1,1
1322 FOR L=104 TO 164 STEP 4:LINE(0,L)-(319,L+1),1,BF:NEXT:GOSUB 450:GOSUB 710:GOTO 1000
1330 GOSUB 1338:LOCATE 23,15:PRINT "<< BEAGLE >>";:GOSUB 740:GOSUB 740:LINE(0,0)-(319,167),0,BF:COLOR 14:P=P-1:CU=2:GOSUB 302:GOSUB 1338:PAINT(160,92),3,1:PAINT(224,88),1,1
1332 GOSUB 460:GOSUB 710:GOTO 1000
1338 LINE(152,150)-(128,143),CU-1:LINE(168,129)-(156,116),CU-1:LINE(148,76)-(160,68),CU-1:LINE(216,80)-(224,101),CU-1:RETURN
1340 GOSUB 1348:LOCATE 23,15:PRINT "<< HAPPY >>";:GOSUB 740:GOSUB 740:LINE(0,0)-(319,167),0,BF:COLOR 13:P=P-1:CU=3:GOSUB 302:PAINT(160,84),3,2:CU=1:GOSUB 1348:PAINT(134,58),1,1:PAINT(186,58),1,1:GOSUB 430:GOSUB 710:GOTO 1000
1348 CIRCLE(160,72),52,CU,3.5,5.9:CIRCLE(160,71),52,CU,3.5,5.9:CIRCLE(186,58),6,CU,,,1.8:CIRCLE(134,58),6,CU,,,1.8:RETURN
1350 GOSUB 1358:LOCATE 23,16:PRINT "<< AUTO >>";:GOSUB 740:GOSUB 740:LINE(0,0)-(319,167),0,BF:COLOR 9:P=P-1:LINE(0,108)-(319,167),1,BF:CU=4:GOSUB 302:GOSUB 1358
1352 PAINT(160,108),2,3:PAINT(160,64),3,3:PAINT(204,132),3,3:PAINT(108,132),3,3:GOSUB 440:GOSUB 710:GOTO 1000
1358 CIRCLE(114,132),16,CU-1:CIRCLE(204,132),16,CU-1:LINE(224,108)-(232,108),CU-1:LINE(232,100)-(233,113),CU-1,BF:LINE(136,92)-(147,93),CU-1,BF:RETURN
1380 GOSUB 1388:LOCATE 23,15:PRINT "<< BUMBLE >>";:GOSUB 740:GOSUB 740:LINE(0,0)-(319,167),0,BF:CU=2:P=P-1:GOSUB 302:GOSUB 1388:PAINT(160,88),1,1:GOSUB 1388:COLOR 12:GOSUB 420:GOSUB 710:GOTO 1000
1388 LINE(144,150)-(176,150),CU-1:DRAW"BM168,24C"+STR$(CU-1)+";NH14R1NH14R4NE14R1NE14":CIRCLE(160,35),2,3:PAINT(160,35),3,3:RETURN
1400 DR=(INT(40-(LEN(NM$)))/2)+1:GOSUB 5000:LOCATE 23,DR-3:PRINT"<< "+NM$+" >>";:A=INT(RND(1)*4)
1406 B=INT(RND(1)*4):IF B=A THEN 1406
1408 CL=INT(RND(1)*16):IF CL=8 OR CL=5 OR CL=7 OR CL=15 OR CL=3 OR CL=0 THEN 1408
1410 COLOR CL:LINE(0,0)-(319,171),A,BF:CU=B+1:P=P-1:GOSUB 302:A=INT(RND(1)*7)+1:ON A GOSUB 420,430,440,450,460,470,480:GOSUB 710:GOTO 1000
1500 RUN"MENU"
2000 IF INKEY$=CHR$(32) THEN RETURN
2100 GOSUB 500:LOCATE 23,4:PRINT"Name the dots and draw a picture!";:B$(0)="0,7":B$(1)="6,-6":B$(2)="-6,3":B$(3)="6,3":B$(4)="-6,-6":B$(5)="0,7":GOSUB 980
2120 GOSUB 3000:GOSUB 404:IF IN$=CHR$(32) THEN RETURN
2122 GOSUB 730:B$=B$(0):GOSUB 664:GOSUB 3000:GOSUB 310
2126 IF IN$=CHR$(32) THEN RETURN
2130 FOR P=1 TO PN:GOSUB 3000:GOSUB 404:GOSUB 730:LOCATE 6,31:B$=B$(P):GOSUB 664:GOSUB 3000:CU=3:GOSUB 300:IF INKEY$=CHR$(32) THEN RETURN
2132 NEXT:P=13:GOSUB 404:GOSUB 710:GOSUB 470:GOSUB 710:RETURN
3000 PUT(A(P)-5,B(P)-4),DT,XOR:RETURN
4000 SCREEN 0,1:COLOR 13,0,0:CLS:LOCATE 1,1,0:PRINT STRING$(40,219);:FOR L=2 TO 23:LOCATE L,1:PRINT CHR$(219);:LOCATE L,40:PRINT CHR$(219);::NEXT:LOCATE 23,1:PRINT STRING$(40,219);:INST=1
4005 COLOR 15,0:LOCATE 4,7:PRINT"DO A DOT-TO-DOT WITH BUMBLE!";:LOCATE 7,7:PRINT"Join the dots by naming the";:LOCATE 8,8:PRINT"number pair for each one.";:LOCATE 11,7:PRINT"In a number pair such as 2,5";
4010 LOCATE 12,7:PRINT"the 2 means go right 2 places";:LOCATE 13,9:PRINT"and the 5 means go up 5.";:LOCATE 15,7:PRINT"You may draw one of Bumble's";:LOCATE 16,7:PRINT"pictures or create your own";
4015 LOCATE 17,11:PRINT"for a friend to do!";:FOR I=1 TO 3000:NEXT
4025 LOCATE 20,2:PRINT"1. BUMBLE'S PICTURES  2. MAKE YOUR OWN";:LOCATE 22,3:PRINT"Pick a number or press <ESC> to stop.";:RETURN
4030 GOSUB 60:IF IN$<>CHR$(27) AND IN$<>CHR$(13) THEN 4030
4035 IF IN$=CHR$(27) THEN GOTO 4070 ELSE RETURN
4060 IN$=INKEY$:IF IN$="" THEN 4060 ELSE RETURN
4070 SCREEN 0,1,0,0:COLOR 15,1,1:CLS:LOCATE 12,1,0:PRINT"Do you want to stop this game? (Y or N)";
4072 GOSUB 60:IF IN$="Y" THEN 1500
4074 IF IN$<>"N" THEN 4072
4080 SCREEN 0,1:COLOR 15,0,0:CLS:RETURN
5000 LOCATE 23,1:PRINT STRING$(79,32);:LOCATE 25,1:PRINT STRING$(39,32);:RETURN
5005 FOR L=22 TO 25:LOCATE L,1:PRINT STRING$(39,32);:NEXT:RETURN
5010 LOCATE 24,1:PRINT STRING$(39,32);:LOCATE 25,1:PRINT STRING$(39,32);:RETURN
5020 LINE(0,192)-(319,199),0,BF:RETURN
5100 DEF SEG=0:POKE 1047,(PEEK(1047) OR 96) AND (223-(32*(PC<>&HFD))):DEF SEG:RETURN
5102 DEF SEG=0:POKE 1047,96+32*(PC=&HFD):DEF SEG:RETURN
5200 GET(62,0)-(287,171),SC:RETURN
5210 SCREEN 1,0:COLOR 0,1:CLS:PUT(62,0),SC,PSET:RETURN
5400 DEF SEG=0:SND=PEEK(1264):DEF SEG:DEF SEG=&HF000:IF PEEK(&HFFFE)=&HFD THEN PC=&HFD
5401 DEF SEG:RETURN
7100 GOSUB 60:IF IN$=CHR$(13) THEN RETURN
7101 IF LEN(NM$)=10 THEN RETURN
7102 IF IN$=CHR$(8) THEN LOCATE 24,16:PRINT STRING$(LEN(NM$),32);:IF NM$="" THEN 7100 ELSE NM$=LEFT$(NM$,LEN(NM$)-1):LOCATE 24,16:IF LEN(NM$)<1 THEN 7100 ELSE LOCATE 24,16:PRINT NM$;:GOTO 7100
7103 IF IN$=CHR$(27) THEN EFLAG7=1:RETURN
7104 NM$=NM$+IN$:LOCATE 24,16:PRINT NM$;:GOTO 7100
8000 DRAW"BM0,0C3NF7D1NF6BD6NE7R1E6":GET(0,0)-(7,7),EX:CLS:CIRCLE(5,4),3,3:PAINT(4,3),3,3:GET(0,0)-(8,6),DT:CLS:RETURN
9000 DATA O2C,O2C#,O2D,O2D#,O2E,O2F,O2F#,O2G,O2G#,O2A,O2A#,O2B,O3C,O3C#,O3D,O3D#,O3E,O3F,O3F#,O3G
9999 RUN